MapQuickItem QML Type

The MapQuickItem type displays an arbitrary Qt Quick object on a Map. More...

• List of all members, including inherited members
• MapQuickItem is part of QML Maps Plugin.

Properties

• anchorPoint : QPointF
• autoFadeIn : bool
• coordinate : coordinate
• sourceItem : object
• zoomLevel : real

Detailed Description

The MapQuickItem type is used to place an arbitrary Qt Quick object on a Map at a specified location and size. Compared to floating an item above the Map, a MapQuickItem will follow the panning (and optionally, the zooming) of the Map as if it is on the Map surface.

The sourceItem property contains the Qt Quick item to be drawn, which can be any kind of visible type.

Positioning and Sizing

The positioning of the MapQuickItem on the Map is controlled by two properties: coordinate and anchorPoint. If only coordinate is set, it specifies a longitude/latitude coordinate for the item to be placed at. The set coordinate will line up with the top-left corner of the contained item when shown on the screen.

The anchorPoint property provides a way to line up the coordinate with other parts of the item than just the top-left corner, by setting a number of pixels the item will be offset by. A simple way to think about it is to note that the point given by anchorPoint on the item itself is the point that will line up with the given coordinate when displayed.

In addition to being anchored to the map, the MapQuickItem can optionally follow the scale of the map, and change size when the Map is zoomed in or zoomed out. This behaviour is controlled by the zoomLevel property. The default behaviour if zoomLevel is not set is for the item to be drawn "on the screen" rather than "on the map", so that its size remains the same regardless of the zoom level of the Map.

Performance

Performance of a MapQuickItem is normally in the same ballpark as the contained Qt Quick item alone. Overheads added amount to a translation and (possibly) scaling of the original item, as well as a transformation from longitude and latitude to screen position.

Limitations

Example Usage

The following snippet shows a MapQuickItem containing an Image object, to display a Marker on the Map. This strategy is used to show the map markers in the MapViewer example.

 MapQuickItem {
     id: marker
     anchorPoint.x: image.width/4
     anchorPoint.y: image.height

     HoverHandler {
         id: hoverHandler
     }
     TapHandler {
         id: tapHandler
         acceptedButtons: Qt.RightButton
         gesturePolicy: TapHandler.WithinBounds
         onTapped: {
             mapview.currentMarker = -1
             for (var i = 0; i< mapview.markers.length; i++){
                 if (marker == mapview.markers[i]){
                     mapview.currentMarker = i
                     break
                 }
             }
             mapview.showMarkerMenu(marker.coordinate)
         }
     }
     DragHandler {
         id: dragHandler
         grabPermissions: PointerHandler.CanTakeOverFromItems | PointerHandler.CanTakeOverFromHandlersOfDifferentType
     }

     sourceItem: Image {
         id: image
     }
 }

Property Documentation